home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 41 / Amiga Format CD41 (1999-06)(Future Publishing)(GB)[!][issue 1999-07].iso / -seriously_amiga- / programming / other / scm / slib / mwsynrul.scm < prev    next >
Text File  |  1999-04-19  |  10KB  |  344 lines
  1. ; "mwsynrul.scm" Compiler for a <transformer spec>.
  2. ; Copyright 1992 William Clinger
  3. ;
  4. ; Permission to copy this software, in whole or in part, to use this
  5. ; software for any lawful purpose, and to redistribute this software
  6. ; is granted subject to the restriction that all copies made of this
  7. ; software must include this copyright notice in full.
  8. ;
  9. ; I also request that you send me a copy of any improvements that you
  10. ; make to this software so that they may be incorporated within it to
  11. ; the benefit of the Scheme community.
  12.  
  13. ;;;; Compiler for a <transformer spec>.
  14.  
  15. ;;; The input is a <transformer spec> and a syntactic environment.
  16. ;;; Syntactic environments are described in another file.
  17.  
  18. ;;; Transormer specs are in slib.texi.
  19.  
  20. (define mw:pattern-variable-flag (list 'v))
  21. (define mw:ellipsis-pattern-flag (list 'e))
  22. (define mw:ellipsis-template-flag mw:ellipsis-pattern-flag)
  23.  
  24. (define (mw:make-patternvar v rank)
  25.   (vector mw:pattern-variable-flag v rank))
  26. (define (mw:make-ellipsis-pattern P vars)
  27.   (vector mw:ellipsis-pattern-flag P vars))
  28. (define (mw:make-ellipsis-template T vars)
  29.   (vector mw:ellipsis-template-flag T vars))
  30.  
  31. (define (mw:patternvar? x)
  32.   (and (vector? x)
  33.        (= (vector-length x) 3)
  34.        (eq? (vector-ref x 0) mw:pattern-variable-flag)))
  35.  
  36. (define (mw:ellipsis-pattern? x)
  37.   (and (vector? x)
  38.        (= (vector-length x) 3)
  39.        (eq? (vector-ref x 0) mw:ellipsis-pattern-flag)))
  40.  
  41. (define (mw:ellipsis-template? x)
  42.   (and (vector? x)
  43.        (= (vector-length x) 3)
  44.        (eq? (vector-ref x 0) mw:ellipsis-template-flag)))
  45.  
  46. (define (mw:patternvar-name V) (vector-ref V 1))
  47. (define (mw:patternvar-rank V) (vector-ref V 2))
  48. (define (mw:ellipsis-pattern P) (vector-ref P 1))
  49. (define (mw:ellipsis-pattern-vars P) (vector-ref P 2))
  50. (define (mw:ellipsis-template T) (vector-ref T 1))
  51. (define (mw:ellipsis-template-vars T) (vector-ref T 2))
  52.  
  53. (define (mw:pattern-variable v vars)
  54.   (cond ((null? vars) #f)
  55.     ((eq? v (mw:patternvar-name (car vars)))
  56.      (car vars))
  57.     (else (mw:pattern-variable v (cdr vars)))))
  58.  
  59. ; Given a <transformer spec> and a syntactic environment,
  60. ; returns a macro denotation.
  61. ;
  62. ; A macro denotation is of the form
  63. ;
  64. ;    (macro (<rule> ...) env)
  65. ;
  66. ; where each <rule> has been compiled as described above.
  67.  
  68. (define (mw:compile-transformer-spec spec env)
  69.   (if (and (> (mw:safe-length spec) 1)
  70.        (eq? (mw:syntax-lookup env (car spec))
  71.         mw:denote-of-syntax-rules))
  72.       (let ((literals (cadr spec))
  73.         (rules (cddr spec)))
  74.     (if (or (not (list? literals))
  75.         (not (comlist:every (lambda (rule)
  76.                   (and (= (mw:safe-length rule) 2)
  77.                    (pair? (car rule))))
  78.                   rules)))
  79.         (mw:error "Malformed syntax-rules" spec))
  80.     (list 'macro
  81.           (map (lambda (rule)
  82.              (mw:compile-rule rule literals env))
  83.            rules)
  84.           env))
  85.       (mw:error "Malformed syntax-rules" spec)))
  86.  
  87. (define (mw:compile-rule rule literals env)
  88.   (mw:compile-pattern (cdr (car rule))
  89.              literals
  90.              env
  91.              (lambda (compiled-rule patternvars)
  92.                ; should check uniqueness of pattern variables here!!!!!
  93.                (cons compiled-rule
  94.                  (mw:compile-template
  95.                   (cadr rule)
  96.                   patternvars
  97.                   env)))))
  98.  
  99. (define (mw:compile-pattern P literals env k)
  100.   (define (loop P vars rank k)
  101.     (cond ((symbol? P)
  102.        (if (memq P literals)
  103.            (k P vars)
  104.            (let ((var (mw:make-patternvar P rank)))
  105.          (k var (cons var vars)))))
  106.       ((null? P) (k '() vars))
  107.       ((pair? P)
  108.        (if (and (pair? (cdr P))
  109.             (symbol? (cadr P))
  110.             (eq? (mw:syntax-lookup env (cadr P))
  111.              mw:denote-of-...))
  112.            (if (null? (cddr P))
  113.            (loop (car P)
  114.              '()
  115.              (+ rank 1)
  116.              (lambda (P vars1)
  117.                (k (mw:make-ellipsis-pattern P vars1)
  118.                   (comlist:union vars1 vars))))
  119.            (mw:error "Malformed pattern" P))
  120.            (loop (car P)
  121.              vars
  122.              rank
  123.              (lambda (P1 vars)
  124.                (loop (cdr P)
  125.                  vars
  126.                  rank
  127.                  (lambda (P2 vars)
  128.                    (k (cons P1 P2) vars)))))))
  129.       ((vector? P)
  130.        (loop (vector->list P)
  131.          vars
  132.          rank
  133.          (lambda (P vars)
  134.            (k (vector P) vars))))
  135.       (else (k P vars))))
  136.   (loop P '() 0 k))
  137.  
  138. (define (mw:compile-template T vars env)
  139.   
  140.   (define (loop T inserted referenced rank escaped? k)
  141.     (cond ((symbol? T)
  142.        (let ((x (mw:pattern-variable T vars)))
  143.          (if x
  144.          (if (>= rank (mw:patternvar-rank x))
  145.              (k x inserted (cons x referenced))
  146.              (mw:error
  147.               "Too few ellipses follow pattern variable in template"
  148.               (mw:patternvar-name x)))
  149.          (k T (cons T inserted) referenced))))
  150.       ((null? T) (k '() inserted referenced))
  151.       ((pair? T)
  152.        (cond ((and (not escaped?)
  153.                (symbol? (car T))
  154.                (eq? (mw:syntax-lookup env (car T))
  155.                 mw:denote-of-:::)
  156.                (pair? (cdr T))
  157.                (null? (cddr T)))
  158.           (loop (cadr T) inserted referenced rank #t k))
  159.          ((and (not escaped?)
  160.                (pair? (cdr T))
  161.                (symbol? (cadr T))
  162.                (eq? (mw:syntax-lookup env (cadr T))
  163.                 mw:denote-of-...))
  164.           (loop1 T inserted referenced rank escaped? k))
  165.          (else
  166.           (loop (car T)
  167.             inserted
  168.             referenced
  169.             rank
  170.             escaped?
  171.             (lambda (T1 inserted referenced)
  172.               (loop (cdr T)
  173.                 inserted
  174.                 referenced
  175.                 rank
  176.                 escaped?
  177.                 (lambda (T2 inserted referenced)
  178.                   (k (cons T1 T2) inserted referenced))))))))
  179.       ((vector? T)
  180.        (loop (vector->list T)
  181.          inserted
  182.          referenced
  183.          rank
  184.          escaped?
  185.          (lambda (T inserted referenced)
  186.            (k (vector T) inserted referenced))))
  187.       (else (k T inserted referenced))))
  188.   
  189.   (define (loop1 T inserted referenced rank escaped? k)
  190.     (loop (car T)
  191.       inserted
  192.       '()
  193.       (+ rank 1)
  194.       escaped?
  195.       (lambda (T1 inserted referenced1)
  196.         (loop (cddr T)
  197.           inserted
  198.           (append referenced1 referenced)
  199.           rank
  200.           escaped?
  201.           (lambda (T2 inserted referenced)
  202.             (k (cons (mw:make-ellipsis-template
  203.                   T1
  204.                   (comlist:remove-if-not
  205.                    (lambda (var) (> (mw:patternvar-rank var)
  206.                         rank))
  207.                    referenced1))
  208.                  T2)
  209.                inserted
  210.                referenced))))))
  211.   
  212.   (loop T
  213.     '()
  214.     '()
  215.     0
  216.     #f
  217.     (lambda (T inserted referenced)
  218.       (list T inserted))))
  219.  
  220. ; The pattern matcher.
  221. ;
  222. ; Given an input, a pattern, and two syntactic environments,
  223. ; returns a pattern variable environment (represented as an alist)
  224. ; if the input matches the pattern, otherwise returns #f.
  225.  
  226. (define mw:empty-pattern-variable-environment
  227.   (list (mw:make-patternvar (string->symbol "") 0)))
  228.  
  229. (define (mw:match F P env-def env-use)
  230.   
  231.   (define (match F P answer rank)
  232.     (cond ((null? P)
  233.        (and (null? F) answer))
  234.       ((pair? P)
  235.        (and (pair? F)
  236.         (let ((answer (match (car F) (car P) answer rank)))
  237.           (and answer (match (cdr F) (cdr P) answer rank)))))
  238.       ((symbol? P)
  239.        (and (symbol? F)
  240.         (mw:same-denotation? (mw:syntax-lookup env-def P)
  241.                      (mw:syntax-lookup env-use F))
  242.         answer))
  243.       ((mw:patternvar? P)
  244.        (cons (cons P F) answer))
  245.       ((mw:ellipsis-pattern? P)
  246.        (match1 F P answer (+ rank 1)))
  247.       ((vector? P)
  248.        (and (vector? F)
  249.         (match (vector->list F) (vector-ref P 0) answer rank)))
  250.       (else (and (equal? F P) answer))))
  251.   
  252.   (define (match1 F P answer rank)
  253.     (cond ((not (list? F)) #f)
  254.       ((null? F)
  255.        (append (map (lambda (var) (cons var '()))
  256.             (mw:ellipsis-pattern-vars P))
  257.            answer))
  258.       (else
  259.        (let* ((P1 (mw:ellipsis-pattern P))
  260.           (answers (map (lambda (F) (match F P1 answer rank))
  261.                 F)))
  262.          (if (comlist:every identity answers)
  263.          (append (map (lambda (var)
  264.                 (cons var
  265.                       (map (lambda (answer)
  266.                          (cdr (assq var answer)))
  267.                        answers)))
  268.                   (mw:ellipsis-pattern-vars P))
  269.              answer)
  270.          #f)))))
  271.   
  272.   (match F P mw:empty-pattern-variable-environment 0))
  273.  
  274. (define (mw:rewrite T alist)
  275.   
  276.   (define (rewrite T alist rank)
  277.     (cond ((null? T) '())
  278.       ((pair? T)
  279.        ((if (mw:ellipsis-pattern? (car T))
  280.         append
  281.         cons)
  282.         (rewrite (car T) alist rank)
  283.         (rewrite (cdr T) alist rank)))
  284.       ((symbol? T) (cdr (assq T alist)))
  285.       ((mw:patternvar? T) (cdr (assq T alist)))
  286.       ((mw:ellipsis-template? T)
  287.        (rewrite1 T alist (+ rank 1)))
  288.       ((vector? T)
  289.        (list->vector (rewrite (vector-ref T 0) alist rank)))
  290.       (else T)))
  291.   
  292.   (define (rewrite1 T alist rank)
  293.     (let* ((T1 (mw:ellipsis-template T))
  294.        (vars (mw:ellipsis-template-vars T))
  295.        (rows (map (lambda (var) (cdr (assq var alist)))
  296.               vars)))
  297.       (map (lambda (alist) (rewrite T1 alist rank))
  298.        (make-columns vars rows alist))))
  299.   
  300.   (define (make-columns vars rows alist)
  301.     (define (loop rows)
  302.       (if (null? (car rows))
  303.       '()
  304.       (cons (append (map (lambda (var row)
  305.                    (cons var (car row)))
  306.                  vars
  307.                  rows)
  308.             alist)
  309.         (loop (map cdr rows)))))
  310.     (if (or (null? (cdr rows))
  311.         (apply = (map length rows)))
  312.     (loop rows)
  313.     (mw:error "Use of macro is not consistent with definition"
  314.          vars
  315.          rows)))
  316.   
  317.   (rewrite T alist 0))
  318.  
  319. ; Given a use of a macro, the syntactic environment of the use,
  320. ; and a continuation that expects a transcribed expression and
  321. ; a new environment in which to continue expansion,
  322. ; does the right thing.
  323.  
  324. (define (mw:transcribe exp env-use k)
  325.   (let* ((m (mw:syntax-lookup env-use (car exp)))
  326.      (rules (macwork:rules m))
  327.      (env-def (macwork:env m))
  328.      (F (cdr exp)))
  329.     (define (loop rules)
  330.       (if (null? rules)
  331.       (mw:error "Use of macro does not match definition" exp)
  332.       (let* ((rule (car rules))
  333.          (pattern (car rule))
  334.          (alist (mw:match F pattern env-def env-use)))
  335.         (if alist
  336.         (let* ((template (cadr rule))
  337.                (inserted (caddr rule))
  338.                (alist2 (mw:rename-vars inserted))
  339.                (newexp (mw:rewrite template (append alist2 alist))))
  340.           (k newexp
  341.              (mw:syntax-alias env-use alist2 env-def)))
  342.         (loop (cdr rules))))))
  343.     (loop rules)))
  344.